//Corrects for uneven illumination in channel 1 = phase contrast
//not suitable for 5D stacks
//Process sequence: Downscale-Median-Upscale-DivideImages-MultiplyByMean
//24.12.16 14:22

macro "Correct Phase contrast illumination"{
	close("Dup_*");
	getDimensions(ww, hh, channels, slices, frames);
	if(minOf(slices, frames) > 1) exit("not suitable for 5D");
	stackID = getImageID;
	for(slc = 1; slc <= nSlices; slc += channels){//not for 5D
		setSlice(slc);
		run("Select None");
		getRawStatistics(area, mean);
		run("Duplicate...", "title=Dup_1");
		run("Scale...", "x=0.1 y=0.1  interpolation=Bilinear average create title=Dup_2");
		run("Median...", "radius=25");
		run("Scale...", "x=- y=- width=&ww height=&hh interpolation=Bilinear average create title=Dup_3");
		imageCalculator("Divide create 32-bit", "Dup_1","Dup_3");
		rename("Dup_4");
		run("Multiply...", "value=&mean");
		resetMinAndMax;
		run("16-bit");
		run("Select All");
		run("Copy");
		selectImage(stackID);
		run("Paste");
		close("Dup_*");
	}
}