/*
Three macros to collect fluor profiles from
several ObjectJ project files

1. Open this file and choose Macros>Install Macros
2. Choose Macros>Prepare Log
3. Open an .ojj project file that contains column "FluorPairs"
4. Choose Plugins>Macros>Add FluorPairs to Log
5. Repeat steps 3 and 4 to add results from other .ojj files
6. Choose Plugins>Macros>Log To Results
	(->this saves and reloads the text into the results)
7. In Results, right-click column title "Fluor" and choose Plot...
8. Choose X=time, Y= fluor, Symbol = circle, click OK
	-> Plot appears
9. In the Plot, click button "Data>>" and choose "Add Fit..."
*/
macro "Prepare Log"{
	print("\\Clear");
	print("Time,FLuor");
}


macro "Add FluorPairs to Log" {
	all = "";
	for(obj = 1; obj <= ojNObjects(); obj++){
		s =  ojResultString("FluorPairs", obj);
		all = all + s;
	}
	all = replace(all, ";", "\n");
	all = replace(all, " ", ",");
	print(all);
}


macro "Log To Results"{
	selectWindow("Log");
	path = getDirectory("temp") + "fluor.csv";
	saveAs("Text", path);
	run("Results... ", "open=" + path);
	
}