/*
Macro removes dark borders of all tiff images 
in "source folder", and stores the resulting 8-bit images
by default in a sub-folder called 'Clean'.
Names of cleaned files end with '_c.tif'

Usage:
1. Open one of the tiff files of source folder
2. Run the macro

06.06.2025, 17:55
*/


macro "Remove Dark Borders"{
	suffix = "_c"; //for cleaned file name
	convexHull = true;
	srcDir = getDir("image");
	list = getFileList(srcDir);
	if(list.length== 0 && (srcDir.contains("/Desktop") || srcDir.contains("/Downloads")))
		exit("Desktop or Downloads access not allowed?");
	print("\\Clear");
	print("-- SrcDir: --\n", srcDir, "\n \n-- srcFiles: --");
	nTifs = 0;
	tiffTitles = "";
	for (i=0; i<list.length; i++) {//extension
		thisTitle= list[i];
		ttl = thisTitle.toLowerCase;
		if (ttl.endsWith(".tiff") || ttl.endsWith(".tif" )){
			tiffTitles += thisTitle +"\t";	
			print(++nTifs, "  ", thisTitle);
		}
	}
	if(nTifs == 0){
		showMessage("One image of source folder must be in front");
		return;
	}
	tiffTitles = split(tiffTitles, "\t");
//	nTifs = tiffTitles.length;
	selectWindow("Log");
	print("---");
	Dialog.create("Select Destination");	
	srcDir = getDir("image");
	label = "Clean and export " + nTifs +" tiff images to:";
	items = split("Sub-folder 'Clean'|Choose...","|"); 
	Dialog.addRadioButtonGroup(label, items, 2, 1, "Sub-folder 'Clean'");
	Dialog.show;
	destDir = srcDir +"Clean";
	if (Dialog.getRadioButton == "Choose..."){
		Dialog.create("Choose destination");
		Dialog.addDirectory("path:", "");
		Dialog.show;
		destDir = Dialog.getString;
	}
	//create clean images
	for(jj = 0; jj < nTifs; jj++){
		title = tiffTitles[jj];
		close(title);
		open(srcDir+title);
		File.makeDirectory(destDir);
		newTitle = replace(title, ".tif", suffix + ".tif");
		
		run("8-bit");
		run("Select None");
		setAutoThreshold("Default dark");
		minSize = getWidth * getHeight *0.4;
		run("Analyze Particles...", "size=&minSize-Infinity pixel clear include add");
		if(roiManager("count")!= 1 || nSlices != 1){
			print("Could not handle: " + title);
			close;
			return;
		}
		roiManager("select", 0);
		//run("Enlarge...", "enlarge=-20 pixel");
		run("Enlarge...", "enlarge=-10 pixel");
		if(convexHull)
			run("Convex Hull");//06.06.2025, 10:50
		run("Remove Overlay");
		mode = getValue("Mode");
		run("Make Inverse");
		resetThreshold;
		run("Set...", "value=&mode");
		run("Make Inverse");
		if(is("Caps Lock Set"))
			waitForUser("Caps Lock Set for visual inspection.\nClick OK to continue");
		run("Crop");
		run("Select None");
		saveAs("Tiff", destDir + "/" + newTitle);
		close;
	}
	close("Roi Manager");
}