//9.1.14 14:21 
//Download LOCI Tools from: http://downloads.openmicroscopy.org/bio-formats/
//click on the "jar" logo with blue arrow, left of "Clients: LOCI Tools"


macro "ND2 to Hyperstack"{
	dir = getDirectory("Choose a Directory ");
	print("\\Clear");
	print("Files to be converted:");
	print("---");
	list = getFileList(dir);
	for (loop = 1; loop <=2; loop++){
		if (loop == 2){
			selectWindow("Log");
			waitForUser;
		}
		for (i=0; i<list.length; i++) {
			name = list[i];
			if (endsWith(name, ".nd2")){
				if (loop == 1){
					print(name);
				}
				if (loop == 2){
					run("Bio-Formats Importer", "open=[" + dir + name + "] color_mode=Grayscale view=Hyperstack stack_order=XYCZT");
					nameTif = substring(name, 0, lengthOf(name) - 3) + "tif";
					getDimensions(dummy, dummy, channels, dummy, dummy);
					for(chn = 1; chn <= channels; chn++){
						Stack.setChannel(chn);
						run("Enhance Contrast", "saturated=0.05");
						wait(200);
					}
					Stack.setChannel(1);
					saveAs("Tiff", dir + nameTif);
					close;
				}
			}
		}
	}
}